Inspect a mixed linked list

// Read-only snapshots show node references; they never call user methods.
import aner.dev

class Node {
    public let value
    public var next: Node?
}

class LinkedList {
    var head: Node?

    fn prepend(value) { head = Node(value: value, next: head) }

    fn append(value) {
        let node = Node(value: value, next: null)
        if head == null { head = node; return }
        var cursor = head
        while cursor.next != null { cursor = cursor.next }
        cursor.next = node
    }

    fn remove_first(value) {
        if head == null { return false }
        if head.value == value { head = head.next; return true }
        var cursor = head
        while cursor.next != null {
            if cursor.next.value == value {
                cursor.next = cursor.next.next
                return true
            }
            cursor = cursor.next
        }
        return false
    }

    fn len() {
        var count = 0
        var cursor = head
        while cursor != null { count = count + 1; cursor = cursor.next }
        return count
    }
}

let items = LinkedList(head: null)
items.append(10)
items.append("hello")
dev.capture("After two appends", items)
items.prepend(1.5)
dev.capture("After prepending a Float64", items)
print(items.remove_first("hello"))
dev.capture("After removing the String node", items)
print(items.len()) // 2 in both development and production